{
  description = "Hi!";

  # The `flake.lock` generation is not computable[1]. So far it's impossible to
  # add helper functions to manage inputs.
  #
  # [1]: https://github.com/NixOS/nix/issues/5373
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
    nixpkgs-master.url = "github:NixOS/nixpkgs/master";
    nixpkgs-stable.url = "github:NixOS/nixpkgs/release-23.11";

    nixos-hardware.url = "github:NixOS/nixos-hardware";

    home-manager = {
      url = "github:nix-community/home-manager";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    stylix = {
      url = "github:danth/stylix";
      inputs = {
        flake-compat.follows = "flake-compat";
        home-manager.follows = "home-manager";
        nixpkgs.follows = "nixpkgs";
      };
    };

    impermanence.url = "github:nix-community/impermanence";

    agenix = {
      url = "github:ryantm/agenix";
      inputs = {
        home-manager.follows = "home-manager";
        nixpkgs.follows = "nixpkgs";
      };
    };

    dns = {
      url = "github:kirelagin/dns.nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    mailserver = {
      url = "gitlab:simple-nixos-mailserver/nixos-mailserver";
      inputs = {
        flake-compat.follows = "flake-compat";
        nixpkgs.follows = "nixpkgs";
      };
    };

    alertmanager-ntfy = {
      url = "github:pinpox/alertmanager-ntfy";
      inputs = {
        flake-compat.follows = "flake-compat";
        nixpkgs.follows = "nixpkgs";
      };
    };

    vscode-extensions = {
      url = "github:nix-community/nix-vscode-extensions";
      inputs = {
        flake-compat.follows = "flake-compat";
        nixpkgs.follows = "nixpkgs";
      };
    };

    arkenfox = {
      url = "github:dwarfmaster/arkenfox-nixos";
      inputs = {
        flake-compat.follows = "flake-compat";
        nixpkgs.follows = "nixpkgs";
        pre-commit.follows = "git-hooks";
      };
    };

    minecraft = {
      url = "github:Infinidoge/nix-minecraft";
      inputs = {
        flake-compat.follows = "flake-compat";
        nixpkgs.follows = "nixpkgs";
      };
    };

    nix-index-database = {
      url = "github:nix-community/nix-index-database";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    nix-topology = {
      url = "github:oddlama/nix-topology";
      inputs = {
        nixpkgs.follows = "nixpkgs";
        pre-commit-hooks.follows = "git-hooks";
      };
    };

    xmonad-ng = {
      url = "git+https://git.azahi.cc/xmonad-ng?ref=master";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    azahi-cc = {
      url = "git+https://git.azahi.cc/azahi-cc?ref=master";
      flake = false;
    };

    nmap-vulners = {
      url = "github:vulnersCom/nmap-vulners";
      flake = false;
    };
    nmap-vulscan = {
      url = "github:scipag/vulscan";
      flake = false;
    };

    git-hooks = {
      url = "github:cachix/git-hooks.nix";
      inputs = {
        flake-compat.follows = "flake-compat";
        nixpkgs.follows = "nixpkgs";
        nixpkgs-stable.follows = "nixpkgs-stable";
      };
    };

    flake-registry = {
      url = "github:NixOS/flake-registry";
      flake = false;
    };
    flake-compat.url = "github:edolstra/flake-compat";
  };

  outputs =
    inputs@{ self, nixpkgs, ... }:
    let
      system = "x86_64-linux";

      pkgs = import nixpkgs {
        inherit system;
        overlays = [
          self.overlays.default
          inputs.nix-topology.overlays.default
        ];
      };
    in
    {
      lib = nixpkgs.lib.extend (import ./lib);

      legacyPackages.${system} = pkgs;

      packages.${system} = {
        default = self.packages.${system}.nixfiles;
        inherit (self.legacyPackages.${system}) nixfiles;

        iso = self.nixosConfigurations.iso.config.system.build.isoImage;
      };

      apps.${system}.default = {
        type = "app";
        program = self.lib.getExe self.packages.${system}.nixfiles;
      };

      overlays = import ./overlays.nix;

      devShells.${system}.default =
        with pkgs;
        mkShell {
          inherit (self.checks.${system}.preCommit) shellHook;
          packages = [ go-task ];
        };

      nixosModules = import ./modules self.lib;

      nixosConfigurations = import ./configurations inputs;

      checks.${system} = import ./checks.nix inputs system pkgs;

      formatter.${system} = pkgs.nixfmt;

      topology = import ./topology.nix inputs self pkgs;
    };
}