{
  description = "nixfiles";

  # `flake.lock` generation is not computable[1], thus it is impossible to add
  # helper functions to manage inputs.
  #
  # [1]: https://github.com/NixOS/nix/issues/5373
  inputs = {
    nixpkgs = {
      # type = "path";
      # path = "/home/azahi/src/nixpkgs";
      type = "github";
      owner = "NixOS";
      repo = "nixpkgs";
      ref = "nixpkgs-unstable";
    };

    nixpkgs-master = {
      type = "github";
      owner = "NixOS";
      repo = "nixpkgs";
      ref = "master";
    };

    nixpkgs-stable = {
      type = "github";
      owner = "NixOS";
      repo = "nixpkgs";
      ref = "release-22.11";
    };

    # For testing PRs and stuff.
    # nixpkgs-local = {
    #   type = "path";
    #   path = "/home/azahi/src/nixpkgs";
    # };

    nixos-hardware = {
      type = "github";
      owner = "NixOS";
      repo = "nixos-hardware";
      ref = "master";
    };

    nur = {
      type = "github";
      owner = "nix-community";
      repo = "NUR";
      ref = "master";
    };

    darwin = {
      type = "github";
      owner = "LnL7";
      repo = "nix-darwin";
      ref = "master";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    home-manager = {
      # type = "path";
      # path = "/home/azahi/src/home-manager";
      type = "github";
      owner = "nix-community";
      repo = "home-manager";
      ref = "master";
      inputs = {
        nixpkgs.follows = "nixpkgs";
        utils.follows = "flake-utils";
      };
    };

    impermanence = {
      type = "github";
      owner = "nix-community";
      repo = "impermanence";
      ref = "master";
    };

    emacs-overlay = {
      type = "github";
      owner = "nix-community";
      repo = "emacs-overlay";
      ref = "master";
      inputs = {
        flake-utils.follows = "flake-utils";
        nixpkgs.follows = "nixpkgs";
      };
    };

    # Waiting for patches[1]. Currently, the new profile feature breaks
    # everything and I don't want to spend 12 hours debugging this shit.
    #
    # [1]: https://github.com/nix-community/nix-doom-emacs/pull/316
    # nix-doom-emacs = {
    #   # type = "path";
    #   # path = "/home/azahi/src/nix-doom-emacs";
    #   type = "github";
    #   owner = "nix-community";
    #   repo = "nix-doom-emacs";
    #   ref = "master";
    #   inputs = {
    #     flake-compat.follows = "flake-compat";
    #     emacs-overlay.follows = "emacs-overlay";
    #     flake-utils.follows = "flake-utils";
    #     nixpkgs.follows = "nixpkgs";
    #   };
    # };

    arkenfox-nixos = {
      type = "github";
      owner = "dwarfmaster";
      repo = "arkenfox-nixos";
      ref = "main";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    nix-minecraft = {
      type = "github";
      owner = "Infinidoge";
      repo = "nix-minecraft";
      ref = "master";
      inputs = {
        nixpkgs.follows = "nixpkgs";
        flake-utils.follows = "flake-utils";
      };
    };

    pollymc = {
      type = "github";
      owner = "fn2006";
      repo = "PollyMC";
      ref = "6.3";
      inputs = {
        flake-compat.follows = "flake-compat";
        nixpkgs.follows = "nixpkgs";
      };
    };

    dns-nix = {
      type = "github";
      owner = "kirelagin";
      repo = "dns.nix";
      ref = "master";
      inputs = {
        flake-utils.follows = "flake-utils";
        nixpkgs.follows = "nixpkgs";
      };
    };

    simple-nixos-mailserver = {
      type = "gitlab";
      owner = "simple-nixos-mailserver";
      repo = "nixos-mailserver";
      ref = "master";
      inputs = {
        flake-compat.follows = "flake-compat";
        nixpkgs-22_11.follows = "nixpkgs-stable";
        nixpkgs.follows = "nixpkgs";
        utils.follows = "flake-utils";
      };
    };

    # TODO Integrate into Altertmanager.
    # alertmanager-gotify = {
    #   type = "git";
    #   url = "https://git.mbosch.me/ma27/alertmanager-gotify";
    #   inputs = {
    #     flake-utils.follows = "flake-utils";
    #     nixpkgs.follows = "nixpkgs";
    #   };
    # };

    flake-utils = {
      type = "github";
      owner = "numtide";
      repo = "flake-utils";
      ref = "main";
    };

    flake-registry = {
      type = "github";
      owner = "NixOS";
      repo = "flake-registry";
      ref = "master";
      flake = false;
    };

    agenix = {
      type = "github";
      owner = "ryantm";
      repo = "agenix";
      ref = "main";
      inputs = {
        nixpkgs.follows = "nixpkgs";
        darwin.follows = "darwin";
      };
    };

    pre-commit-hooks = {
      type = "github";
      owner = "cachix";
      repo = "pre-commit-hooks.nix";
      ref = "master";
      inputs = {
        flake-compat.follows = "flake-compat";
        flake-utils.follows = "flake-utils";
        nixpkgs.follows = "nixpkgs";
        nixpkgs-stable.follows = "nixpkgs-stable";
      };
    };

    xmonad-ng = {
      # type = "path";
      # path = "/home/azahi/src/xmonad-ng";
      url = "git+https://git.azahi.cc/xmonad-ng?ref=master";
      inputs = {
        flake-utils.follows = "flake-utils";
        nixpkgs.follows = "nixpkgs";
      };
    };

    azahi-cc = {
      url = "git+https://git.azahi.cc/azahi-cc?ref=master";
      flake = false;
    };

    nmap-vulners = {
      type = "github";
      owner = "vulnersCom";
      repo = "nmap-vulners";
      ref = "master";
      flake = false;
    };

    nmap-vulscan = {
      type = "github";
      owner = "scipag";
      repo = "vulscan";
      ref = "master";
      flake = false;
    };

    flake-compat = {
      type = "github";
      owner = "edolstra";
      repo = "flake-compat";
      ref = "master";
      flake = false;
    };
  };

  outputs = inputs:
    with inputs; let
      lib = nixpkgs.lib.extend (import ./lib);
    in
      flake-utils.lib.eachDefaultSystem
      (system: let
        pkgs = import nixpkgs {
          inherit system;
          overlays = [self.overlays.default];
        };
      in {
        # TODO Add packages from `self.overlay.default`.
        packages = with lib;
          (mapAttrs (_: c: c.config.system.build.toplevel)
            (builtins.removeAttrs self.nixosConfigurations ["iso-arm" "iso-x86"]))
          // (let
            buildIsoImage = name: self.nixosConfigurations.${name}.config.system.build.isoImage;
          in {
            iso-arm = buildIsoImage "iso-arm";
            iso-x86 = buildIsoImage "iso-x86";
          })
          // {
            default = pkgs.nixfiles;
          };

        apps.${system}.default = {
          type = "app";
          package = "${self.packages.${system}.default}/bin/nixfiles";
        };

        devShells.default = pkgs.mkShell {
          inherit (self.checks.${system}.preCommit) shellHook;
        };

        # This interface is very primitive...
        formatter = pkgs.writeShellApplication {
          name = "fmt";
          runtimeInputs = with pkgs; [alejandra];
          text = ''
            alejandra --quiet "$@"
          '';
        };

        checks.preCommit = pre-commit-hooks.lib.${system}.run {
          src = ./.;
          hooks = {
            alejandra.enable = true;
            deadnix.enable = true;
            editorconfig-checker.enable = true;
            prettier = {
              enable = true;
              files = "\\.css";
            };
            shellcheck.enable = true;
            shfmt.enable = true;
            statix.enable = true;
            typos = {
              enable = true;
              types = ["text"];
            };
          };
          settings.deadnix.edit = true;
        };
      })
      // {
        inherit lib;

        modules.nixfiles = import ./modules/common;

        nixosModules.nixfiles = import ./modules/nixos;
        nixosConfigurations =
          import ./nixosConfigurations {inherit inputs lib;};

        darwinModules.nixfiles = import ./modules/darwin;
        darwinConfigurations =
          import ./darwinConfigurations {inherit inputs lib;};

        # TODO Make it so that self.packages also can use this.
        overlays.default = final: _: {
          bruh = final.callPackage ./packages/bruh.nix {};
          mpv-autosub = final.callPackage ./packages/mpv-autosub.nix {};
          myip = final.callPackage ./packages/myip.nix {};
          nixfiles = final.callPackage ./packages/nixfiles.nix {};
          throttled = final.callPackage ./packages/throttled.nix {};
        };
      };
}