{
  config,
  inputs,
  lib,
  this,
  ...
}:
with lib; {
  _module.args = let
    importNixpkgsx86 = nixpkgs:
      import nixpkgs {
        inherit (config.nixpkgs) config;
        system = "x86_64-darwin";
      };
  in rec {
    pkgsx86 = importNixpkgsx86 inputs.nixpkgs;
    pkgsLocalx86 = importNixpkgsx86 "${config.my.home}/src/nixpkgs"; # Impure!
    pkgsMasterx86 = importNixpkgsx86 inputs.nixpkgs-master;
    pkgsStablex86 = importNixpkgsx86 inputs.nixpkgs-stable;
    pkgsRevx86 = rev: hash:
      importNixpkgsx86 (pkgs.fetchFromGitHub {
        owner = "NixOS";
        repo = "nixpkgs";
        inherit rev hash;
      });
    pkgsPrx86 = pr: pkgsRevx86 "refs/pull/${toString pr}/head";
  };

  nix = {
    daemonIOLowPriority = false;
    daemonProcessType = "Standard";

    settings.extra-platforms = optionalString (this.system == "aarch64-darwin") ''
      x86_64-darwin aarch64-darwin
    '';

    settings.trusted-users = ["@admin"];
  };

  services.nix-daemon.enable = true;

  # https://github.com/LnL7/nix-darwin/blob/master/CHANGELOG
  system.stateVersion = 4;
}