{
  config,
  lib,
  pkgs,
  this,
  ...
}:
with lib; {
  nixfiles.modules = {
    ark.enable = true;

    wireguard.client.enable = true;

    syncthing.enable = true;

    openssh.server.enable = true;

    games = {
      lutris.enable = true;
      minecraft.client.enable = true;
      steam.enable = true;
    };
    android.enable = true;
    bluetooth.enable = true;
    discord.enable = true;
    libvirtd.enable = true;
    qutebrowser.enable = true;
    mpd.enable = true;
  };

  hm = {
    home.packages = with pkgs; [obs-studio];

    programs = {
      # NOTE This produces very poor performance even though RX 6750 XT should
      # handle VA-API hardware decoding for all major formats (including AV1) just
      # fine.
      firefox.profiles.default.settings."media.ffmpeg.vaapi.enabled" = false;

      # Mostly just placebo. :^)
      mpv.config = {
        hwdec = "vdpau";
        vo = "gpu";
        profile = "gpu-hq";
      };
    };
  };

  # Usually stuff that is going to be compiled on this machine is going to have
  # parallelisation support enabled, so we will make sure that all cores are
  # utilised and limit the job queue to one.
  nix.extraOptions = ''
    keep-going = true
    max-jobs = 1
    cores = 32
  '';

  boot = {
    # TODO Override Xanmod kernel to support ZFS. This probably will require
    # some patching and whatnot.
    kernelPackages = config.boot.zfs.package.latestCompatibleLinuxPackages;

    # Silence benign MCE errors:
    # ```
    # mce: [Hardware Error]: CPU 1: Machine Check: 0 Bank 29: ffffffffffffffff
    # mce: [Hardware Error]: TSC 0 MISC ff1fffffffffffff SYND ffffffffffffffff IPID ffffffffffffffff
    # mce: [Hardware Error]: PROCESSOR 2:a60f12 TIME 1669988017 SOCKET 0 APIC 2 microcode a601201
    # ```
    kernelParams = ["mce=nobootlog"];

    # The boot drive is Samsung SSD 980 PRO 2TB.
    initrd.kernelModules = ["nvme"];
  };

  # Filesystem creation:
  # ```
  # mkfs.vfat -F 32 -l nixos-boot /dev/nvmeXnYpZ
  #
  # zpool create
  # -o ashift=12
  # -o autotrim=on
  # -O acltype=posixacl
  # -O xattr=sa
  # -O compression=zstd
  # -O atime=off
  # -O relatime=off
  # -O devices=off
  # -O canmount=off
  # -O mountpoint=none
  # nixos
  # /dev/nvmeXnYpZ
  #
  # zfs create
  # nixos/root
  #
  # zfs create
  # -o mountpoint=legacy
  # -o relatime=on
  # -o encryption=on
  # -o keyformat=passphrase
  # nixos/root/ark
  #
  # zfs create
  # -o mountpoint=legacy
  # nixos/root/nix
  # ```
  fileSystems = {
    "/boot" = {
      device = "/dev/disk/by-uuid/1363-02E6";
      fsType = "vfat";
    };

    "/" = {
      device = "none";
      fsType = "tmpfs";
      options = ["size=8G" "mode=755"];
    };

    "/ark" = {
      device = "nixos/root/ark";
      fsType = "zfs";
      neededForBoot = true;
    };

    "/nix" = {
      device = "nixos/root/nix";
      fsType = "zfs";
      neededForBoot = true;
    };
  };

  # No swap space is declared here because the system already has 128Gb of RAM. :^)
  # I've only manage to hit around 100Gb mark when running large
  # computations/compiling something big. Pretty sure that a hefty chunk of it
  # was just residual cache and it wouldn't make me get to OOM situations.
}