{
  SDL2,
  autoPatchelfHook,
  cmake,
  curl,
  fetchFromGitHub,
  lib,
  lz4,
  makeWrapper,
  ninja,
  p7zip,
  pkg-config,
  stdenv,
  zenity,
}:
stdenv.mkDerivation {
  pname = "lampray";
  version = "1.4.0-unstable-2024-05-25";

  src = fetchFromGitHub {
    owner = "CHollingworth";
    repo = "Lampray";
    rev = "c549fbfbd6ad18b2eca0a6d17b6066d1f74c54b7";
    hash = "sha256-tjFxHU2kFS5yX0itm4rGKLE7lm/NMgsRjTEGykJELv8=";
  };

  nativeBuildInputs = [
    autoPatchelfHook
    cmake
    makeWrapper
    ninja
    pkg-config
  ];

  buildInputs = [
    SDL2
    curl
    lz4
  ];

  postPatch = ''
    substituteInPlace Lampray/Control/lampConfig.cpp \
      --replace-fail '/usr/libexec/p7zip/7z.so' '${p7zip.lib}/lib/p7zip/7z.so'
  '';

  installPhase = ''
    runHook preInstall

    install -Dm755 Lampray $out/bin/lampray
    wrapProgram $out/bin/lampray \
      --prefix PATH : "${lib.makeBinPath [ zenity ]}"

    runHook postInstall
  '';

  meta = with lib; {
    description = "Mod manager for gaming on Linux";
    homepage = "https://github.com/CHollingworth/Lampray";
    license = with licenses; [
      unlicense
      mpl20 # bit7z
      mit # json & pugixml
      bsd2 # l4z
      gpl2Only # l4z
    ];
    platforms = [ "x86_64-linux" ];
    maintainers = with maintainers; [ azahi ];
    sourceProvenance = with sourceTypes; [ binaryNativeCode ];
    mainProgram = "lampray";
  };
}