1 files changed, 56 insertions, 0 deletions
diff --git a/x11-misc/focus/focus-9999.ebuild b/x11-misc/focus/focus-9999.ebuild
new file mode 100644
index 0000000..10b5dae
--- /dev/null
+++ b/x11-misc/focus/focus-9999.ebuild
@@ -0,0 +1,56 @@
+# Copyright 2019-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+if [[ ${PV} == *9999 ]]; then
+	SCM="git-r3"
+	EGIT_REPO_URI="https://github.com/phillbush/focus.git"
+fi
+
+inherit toolchain-funcs ${SCM}
+
+DESCRIPTION="Focus the closest window in a given direction"
+HOMEPAGE="https://github.com/phillbush/focus"
+
+if [[ ${PV} == *9999 ]]; then
+	SRC_URI=""
+	KEYWORDS=""
+else
+	SRC_URI="https://github.com/phillbush/focus/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE=""
+
+DEPEND="
+	x11-libs/libX11
+	x11-libs/libXinerama
+"
+RDEPEND="${DEPEND}"
+BDEPEND=""
+
+DOCS=( README )
+
+src_prepare() {
+	default
+
+	sed -e '/^CPPFLAGS/d' \
+		-e 's/^CFLAGS =/CFLAGS +=/g' \
+		-e 's/^LDFLAGS =/LDFLAGS +=/g' \
+		-i config.mk || die
+}
+
+src_compile() {
+	emake \
+		CC="$(tc-getCC)"
+}
+
+src_install() {
+	emake install \
+		DESTDIR="${D}" \
+		PREFIX="${EPREFIX}/usr"
+	einstalldocs
+}