From bb9b17b3eb3da9c2f01de0ad891d9758e326179e Mon Sep 17 00:00:00 2001
From: Azat Bahawi <azahi@teknik.io>
Date: Fri, 5 Feb 2021 17:11:00 +0300
Subject: x11-misc/pmenu: Bump version, update building

Package-Manager: Portage-3.0.14, Repoman-3.0.2
Signed-off-by: Azat Bahawi <azahi@teknik.io>
---
 x11-misc/pmenu/pmenu-2.2.0.ebuild | 60 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 60 insertions(+)
 create mode 100644 x11-misc/pmenu/pmenu-2.2.0.ebuild

(limited to 'x11-misc/pmenu/pmenu-2.2.0.ebuild')

diff --git a/x11-misc/pmenu/pmenu-2.2.0.ebuild b/x11-misc/pmenu/pmenu-2.2.0.ebuild
new file mode 100644
index 0000000..b1569c4
--- /dev/null
+++ b/x11-misc/pmenu/pmenu-2.2.0.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+if [[ ${PV} == *9999 ]]; then
+	SCM="git-r3"
+	EGIT_REPO_URI="https://github.com/phillbush/pmenu.git"
+fi
+
+inherit toolchain-funcs ${SCM}
+
+DESCRIPTION="A pie-menu in xlib and imlib2"
+HOMEPAGE="https://github.com/phillbush/pmenu"
+
+if [[ ${PV} == *9999 ]]; then
+	SRC_URI=""
+	KEYWORDS=""
+else
+	SRC_URI="https://github.com/phillbush/pmenu/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE=""
+
+DEPEND="media-libs/fontconfig
+	media-libs/imlib2
+	x11-libs/libX11
+	x11-libs/libXext
+	x11-libs/libXft
+	x11-libs/libXinerama
+	x11-libs/libXrender
+"
+RDEPEND="${DEPEND}"
+BDEPEND=""
+
+DOCS=( README.md )
+
+src_prepare() {
+	default
+
+	sed -e '/^CPPFLAGS/d' \
+		-e 's/^CFLAGS =/CFLAGS +=/g' \
+		-e 's/^LDFLAGS =/LDFLAGS +=/g' \
+		-i config.mk || die
+}
+
+src_compile() {
+	emake \
+		CC="$(tc-getCC)"
+}
+
+src_install() {
+	emake install \
+		DESTDIR="${D}" \
+		PREFIX="${EPREFIX}/usr"
+	einstalldocs
+}
-- 
cgit 1.4.1