{
  description = "Personal XMonad configuration.";

  inputs.nixpkgs = {
    type = "github";
    owner = "NixOS";
    repo = "nixpkgs";
    ref = "nixpkgs-unstable";
  };

  outputs = { nixpkgs, ... }:
    let
      system = "x86_64-linux";

      pkgs = import nixpkgs { inherit system; };

      project = returnShellEnv:
        pkgs.haskellPackages.developPackage {
          inherit returnShellEnv;
          name = "xmonad-ng";
          root = ./.;
          overrides = self: _:
            with pkgs.haskell.lib;
            let version = "0.17.0";
            in {
              xmonad = dontCheck (self.callHackage "xmonad" version { });
              xmonad-contrib =
                dontCheck (self.callHackage "xmonad-contrib" version { });
            };
          modifier = drv:
            pkgs.haskell.lib.addBuildTools drv (with pkgs.haskellPackages; [
              brittany
              cabal-install
              haskell-language-server
              hlint
              hpack
              stack
            ]);
        };
    in {
      defaultPackage.${system} = project false;

      devShell.${system} = project true;
    };
}