2023-11-13

1 files changed, 73 insertions, 0 deletions

diff --git a/overlays.nix b/overlays.nix
new file mode 100644
index 0000000..7229f42
--- /dev/null
+++ b/overlays.nix
@@ -0,0 +1,73 @@
+final: prev: {
+  bruh = prev.callPackage ./packages/bruh.nix {};
+
+  hiccup = prev.callPackage ./packages/hiccup.nix {};
+
+  mpv-autosub = prev.callPackage ./packages/mpv-autosub.nix {};
+
+  myip = prev.callPackage ./packages/myip.nix {};
+
+  nixfiles = prev.callPackage ./packages/nixfiles.nix {};
+
+  openssl_1_0_0 = prev.callPackage ./packages/openssl_1_0_0.nix {};
+
+  logcli = prev.grafana-loki.overrideAttrs (_: super: {
+    pname = "logcli";
+    subPackages = ["cmd/logcli"];
+    nativeBuildInputs = super.nativeBuildInputs ++ [final.installShellFiles];
+    postInstall = ''
+      installShellCompletion --cmd logcli \
+        --bash <($out/bin/logcli --completion--script-bash) \
+        --zsh <($out/bin/logcli --completion-script-zsh)
+    '';
+    preFixup = null;
+  });
+
+  grc = prev.grc.overrideAttrs (_: _: {
+    version = "unstable-2021-08-12";
+    src = final.fetchFromGitHub {
+      owner = "garabik";
+      repo = "grc";
+      rev = "4d6a51fd78ad7e19af8dd12b2a828d1807267079";
+      hash = "sha256-SmOZrgV0lgLryFoxADU15IKJ7jhxXar0MgbsV/z1GaE=";
+    };
+    patches = [
+      (final.fetchpatch {
+        url = "https://patch-diff.githubusercontent.com/raw/garabik/grc/pull/214.patch";
+        hash = "sha256-VNr9jl5oFbFNJbGsjflwFV3oTbCzJ0lBIZA4eyeoXLY=";
+      })
+    ];
+  });
+
+  alejandra = prev.alejandra.overrideAttrs (_: super: {
+    patches = super.patches ++ [./patches/alejandra-no-noise.patch];
+  });
+
+  prismlauncher-unwrapped =
+    (prev.prismlauncher-unwrapped.override (finalAttrs: {
+      stdenv = final.useMoldLinker finalAttrs.stdenv;
+    }))
+    .overrideAttrs (_: super: {
+      patches = super.patches ++ [./patches/prismlauncher-allow-offline-accounts.patch];
+    });
+
+  telegram-desktop =
+    (prev.telegram-desktop.override (finalAttrs: {
+      stdenv = final.useMoldLinker finalAttrs.stdenv;
+    }))
+    .overrideAttrs (_: super: {
+      patches = super.patches ++ [./patches/telegram-desktop-no-ads.patch];
+    });
+
+  vesktop = prev.vesktop.overrideAttrs (_: super: {
+    nativeBuildInputs = super.nativeBuildInputs ++ [final.imagemagick];
+    patches = super.patches ++ [./patches/vesktop-no-anime.patch];
+    postInstall = ''
+      rm -rf $out/share/icons/hicolor/*
+      for size in 16 24 32 48 64 96; do
+        convert -scale $size icon.png $size.png
+        install -Dm644 $size.png $out/share/icons/hicolor/''${size}x''${size}/apps/vencorddesktop.png
+      done
+    '';
+  });
+}