1 files changed, 91 insertions, 0 deletions
diff --git a/modules/common/fonts.nix b/modules/common/fonts.nix
new file mode 100644
index 0000000..483de0d
--- /dev/null
+++ b/modules/common/fonts.nix
@@ -0,0 +1,91 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}:
+with lib; let
+  cfg = config.nixfiles.modules.fonts;
+in {
+  imports = [
+    (mkAliasOptionModule ["fontScheme"] [
+      "nixfiles"
+      "modules"
+      "fonts"
+      "fontScheme"
+    ])
+  ];
+
+  options.nixfiles.modules.fonts = {
+    enable = mkEnableOption "fonts and their configurations";
+
+    fontScheme = let
+      mkFont = {
+        family,
+        style,
+        size,
+      }: {
+        family = mkOption {
+          description = "Family of the font.";
+          type = types.str;
+          default = family;
+        };
+        style = mkOption {
+          description = "Style of the font.";
+          type = types.str;
+          default = style;
+        };
+        size = mkOption {
+          description = "Size of the font.";
+          type = types.int;
+          default = size;
+        };
+      };
+    in {
+      serifFont = mkFont {
+        family = "Iosevka Etoile";
+        style = "Regular";
+        size = 14;
+      };
+
+      serifFontFallback = mkFont {
+        family = "Sarasa Gothic J";
+        style = "Regular";
+        size = 14;
+      };
+
+      sansSerifFont = mkFont {
+        family = "Iosevka Aile";
+        style = "Regular";
+        size = 14;
+      };
+
+      sansSerifFontFallback = mkFont {
+        family = "Sarasa Gothic J";
+        style = "Regular";
+        size = 14;
+      };
+
+      monospaceFont = mkFont {
+        family = "Iosevka";
+        style = "Regular";
+        size = 14;
+      };
+
+      monospaceFontFallback = mkFont {
+        family = "Sarasa Mono J";
+        style = "Regular";
+        size = 14;
+      };
+    };
+  };
+
+  config = mkIf cfg.enable {
+    fonts.fonts = with pkgs; [
+      iosevka-bin
+      (iosevka-bin.override {variant = "aile";})
+      (iosevka-bin.override {variant = "etoile";})
+      sarasa-gothic
+    ];
+  };
+}