blob: c89fba5f511abc18dee26ed25e323421b7acfb02 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
|
{
config,
inputs,
lib,
localUsername ? lib.my.username,
pkgs,
this,
...
}:
with lib; let
cfg = config.nixfiles.modules.emacs;
in {
options.nixfiles.modules.emacs.enable = mkEnableOption "GNU Emacs";
config = mkIf cfg.enable {
secrets.authinfo = {
file = "${inputs.self}/secrets/authinfo";
owner = localUsername;
};
nixfiles.modules = {
fonts.enable = true;
git.client.enable = true;
gnupg.enable = true;
};
hm = {
xdg.configFile = {
"doom/init.el".source = ./doom/init.el;
"doom/packages.el".source = ./doom/packages.el;
"doom/config.el" = {
text = concatStringsSep "\n" [
(let
# NOTE gopls will require the "go" executable which must be provided
# by the project's flake/shell.
extraBins = with pkgs;
[
(aspellWithDicts (p: with p; [en ru])) # :checkers (spell +aspell)
(python3.withPackages (p:
with p; [
black # :lang python :editor format
isort # :lang python
pyflakes # :lang python
python-lsp-server # :lang (python +lsp)
]))
asmfmt # :editor format
bash-language-server # :lang (sh +lsp)
clang-tools # :lang (cc +lsp) :editor format
cmake # :term vterm
cmake-format # :lang cc :editor format
cmigemo # :lang japanese
css-language-server # :lang (web +lsp)
dhall-language-server # :lang (dhall +lsp)
dockerfile-language-server # :tools (docker +lsp)
editorconfig # :tools editorconfig
fd # doom!
gcc # :tools magit :term vterm
gnuplot # :lang (org +gnuplot)
gnutls # doom!
go-language-server # :lang (go +lsp)
gomodifytags # :lang go
gore # :lang go
gotests # :lang go
gotools # :lang go
graphviz # :lang (org +roam2) :lang plantuml
html-language-server # :lang (web +lsp)
html-tidy # :lang web
jre # :lang plantuml
json-language-server # :lang (json +lsp)
libtool # :term vterm
nix-language-server # :lang (nix +lsp)
nodePackages.eslint # :lang (json +lsp)
nodePackages.js-beautify # :lang web
nodePackages.prettier # :editor format
nodePackages.stylelint # :lang web
nodejs # :tools debugger
pandoc # :lang org markdown latex
perl # term vterm
pinentry-emacs # doom!
pre-commit # :tools magit
ripgrep # doom!
rust-analyzer # :lang (rust +lsp)
rustfmt # :lang rust
shellcheck # :lang sh
shfmt # :lang sh :editor format
sqlite # :lang (org +roam2) :tools lookup
texlab # lang (tex +lsp)
texlive.combined.scheme-full # :lang org tex
unzip # :tools debugger
wordnet # :tools (lookup +dictionary +offline)
yaml-language-server # :lang (yaml +lsp)
zls # :lang (zig +lsp)
zstd # :emacs undo
]
++ (
#
# GDB doesn't support[1] Apple Silicon on MacOS.
#
# [1]: https://inbox.sourceware.org/gdb/6b48224b-9e2e-518d-793b-df4fc5514884@arm.com/
if (this.system != "aarch64-darwin")
then [gdb] # :tools debugger
else [lldb] # :tools debugger
)
++ optionals (!pkgs.stdenv.isDarwin)
[
# NOTE Haskell is pretty much broken every couple of days on
# MacOS and I usually don't write anything in Haskell while
# I'm on my work laptop, so... ShellCheck seems to be working,
# though.
haskellPackages.ormolu # :lang haskell :editor format
haskellPackages.haskell-language-server # :lang (haskell +lsp)
haskellPackages.cabal-fmt # :lang haskell :editor format
haskellPackages.cabal-install # :lang haskell
haskellPackages.hoogle # :lang haskell
];
in ''
;; This will integrate packages which are required by various
;; modules without polluting the user's profile.
(setq exec-path (append exec-path '(${
concatMapStringsSep " " (x: ''"${x}/bin"'') extraBins
})))
(setenv "PATH" (concat (getenv "PATH") ":${
concatMapStringsSep ":" (x: "${x}/bin") extraBins
}"))
(appendq! auth-sources '("${config.secrets.authinfo.path}"))
;; Font must be set to N+2 because otherwise it looks too small.
(setq doom-font (font-spec
:family "${config.fontScheme.monospaceFont.family}"
:size ${toString (config.fontScheme.monospaceFont.size + 2)})
doom-unicode-font doom-font)
;; :app irc
(setq circe-default-nick "${my.username}"
circe-default-realname "${my.email}"
circe-default-user circe-default-nick)
;; :lang plantuml
(setq org-plantuml-jar-path "${pkgs.plantuml}/lib/plantuml.jar")
;; :input japanese
(setq migemo-dictionary "${pkgs.cmigemo}/share/migemo/utf-8/migemo-dict")
;; :input japanese
(setq skk-large-jisyo "${pkgs.skk-dicts}/share/skk/SKK-JISYO.L")
;; :lang nix
(setq nix-nixfmt-bin "${pkgs.writeShellScript "nixfmt" ''
${pkgs.alejandra}/bin/alejandra --quiet "$@"
''}")
'')
(with config.hm.accounts.email; let
mu4eAccounts = let
muAccounts = filter (a: a.mu.enable) (attrValues accounts);
in
concatMapStringsSep "\n" (a:
with a; let
personalAddresses = concatMapStringsSep " " (v: ''"${v}"'') aliases;
in ''
(set-email-account! "${name}"
'((user-full-name . "${realName}")
(user-mail-address . "${address}")
(mu4e-inbox-folder . "/${name}/${folders.inbox}")
(mu4e-sent-folder . "/${name}/${folders.sent}")
(mu4e-drafts-folder . "/${name}/${folders.drafts}")
(mu4e-trash-folder . "/${name}/${folders.trash}")
(mu4e-refile-folder . "/${name}/Archive")
(+mu4e-personal-addresses (list ${personalAddresses})))
t)
'')
muAccounts;
in ''
(setq mu4e-root-maildir "${maildirBasePath}")
${mu4eAccounts}
'')
(builtins.readFile ./doom/config.el)
];
onChange = with config.hm.programs; ''
export DOOMDIR="$HOME/.config/doom"
export EMACSDIR="$HOME/.config/emacs"
if [[ ! -d "$EMACSDIR/.git" ]]; then
${git.package}/bin/git clone --depth=1 --branch=master \
"https://github.com/doomemacs/doomemacs" "$EMACSDIR"
fi
if [[ ! -d "$DOOMDIR" ]]; then
mkdir -p "$DOOMDIR/snippets"
fi
if [[ -x "$EMACSDIR/bin/doom" ]]; then
oldpath="$PATH"
export PATH="''${PATH:-/bin}:${emacs.package}/bin:${git.package}/bin"
"$EMACSDIR/bin/doom" sync -e -p --force --verbose
export PATH="$oldpath"
unset oldpath
fi
'';
};
};
programs.emacs = {
enable = true;
package = pkgs.emacs28; # Pin to avoid surprises.
};
};
};
}
|
