modules/nixfiles/firefox/default.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53

{
  config,
  lib,
  pkgs,
  ...
}:
with lib; let
  cfg = config.nixfiles.modules.firefox;
in {
  options.nixfiles.modules.firefox.enable = mkEnableOption "";

  config = mkIf cfg.enable {
    hm = {
      home = {
        # sessionVariables.BROWSER = mkOverride 200 "firefox";

        packages = with pkgs; [
          (writeShellScriptBin "firefox-vanilla" ''
            ${config.hm.programs.firefox.package}/bin/firefox -p vanilla $@
          '')
          profile-cleaner
        ];
      };

      programs.firefox = {
        enable = true;

        package = pkgs.firefox.override {
          cfg = with config.nixfiles.modules; {
            enablePlasmaBrowserIntegration = kde.enable;
            enableGnomeExtensions = gnome.enable;
          };
        };

        profiles.default = (import ./profile.nix) config lib;

        extensions = with pkgs.nur.repos.rycee.firefox-addons;
          [
            bitwarden
            darkreader
            ipfs-companion
            noscript
            privacy-redirect
            refined-github
            stylus
            ublock-origin
            violentmonkey
          ]
          ++ optional config.nixfiles.modules.kde.enable plasma-integration;
      };
    };
  };
}