modules/nixfiles/vim/default.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55

{
  config,
  lib,
  pkgs,
  ...
}:
with lib; let
  cfg = config.nixfiles.modules.vim;
in {
  options.nixfiles.modules.vim.enable = mkEnableOption "Vim";

  config = mkIf cfg.enable {
    programs.vim.package = with pkgs;
      ((vim_configurable.override {features = "normal";}
          // listToAttrs
          (map (name: nameValuePair name false) [
            "cscopeSupport"
            "darwinSupport"
            "guiSupport"
            "luaSupport"
            "multibyteSupport"
            "netbeansSupport"
            "nlsSupport"
            "perlSupport"
            "pythonSupport"
            "rubySupport"
            "tclSupport"
            "ximSupport"
          ]))
        .overrideAttrs (_: super: {
          configureFlags =
            super.configureFlags
            ++ ["--enable-gpm=no" "--enable-gui=no"];
        }))
      .customize {
        name = "vim";
        vimrcConfig = {
          customRC = readFile ./rc.vim;
          packages.myVimPackage.start = with vimPlugins; [
            editorconfig-vim
            vim-eunuch
            vim-nix
            vim-sleuth
            vim-surround
            vim-unimpaired
          ];
        };
      };

    environment = {
      systemPackages = [config.programs.vim.package];
      variables.EDITOR = mkOverride 100 "vim";
    };
  };
}