modules/nixos/nginx.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99

{
  config,
  lib,
  pkgs,
  this,
  ...
}:
with lib; let
  cfg = config.nixfiles.modules.nginx;
in {
  options.nixfiles.modules.nginx = {
    enable = mkEnableOption "Nginx";

    upstreams = mkOption {
      description = "Defines a group of servers to use as proxy target.";
      type = with types; anything;
      default = null;
    };

    virtualHosts = mkOption {
      description = "Attrset of virtual hosts.";
      type = with types; anything;
      default = null;
    };
  };

  config = mkIf cfg.enable {
    services = {
      nginx = {
        enable = true;
        enableReload = true;

        package = pkgs.nginxMainline;

        statusPage = true;

        serverTokens = false;

        recommendedGzipSettings = true;
        recommendedOptimisation = true;
        recommendedProxySettings = true;
        recommendedTlsSettings = true;

        commonHttpConfig = concatStrings [
          ''
            add_header X-Robots-Tag "noindex, nofollow, noarchive, nosnippet";
          ''
          (optionalString (hasAttr "wireguard" this)
            (with config.nixfiles.modules.wireguard; ''
              geo $internal {
                default 0;
                127.0.0.1/32 1;
                ::1/128 1;
                ${ipv4.subnet} 1;
                ${ipv6.subnet} 1;
              }
            ''))
        ];

        inherit (cfg) upstreams;

        virtualHosts =
          {
            default = {
              default = true;
              rejectSSL = true;
              locations."/".return = "444";
            };
          }
          // (mkIf (cfg.virtualHosts != null) (mapAttrs (_: attr:
            mkMerge [
              attr
              (mkIf config.nixfiles.modules.acme.enable {
                enableACME = true;
                forceSSL = true;
              })
            ])
          cfg.virtualHosts));
      };

      fail2ban.jails = {
        nginx-http-auth = ''
          enabled = true
        '';
        nginx-botsearch = ''
          enabled = true
        '';
      };

      prometheus.exporters.nginx = {
        enable = true;
        listenAddress = mkDefault this.wireguard.ipv4.address;
        port = mkDefault 9113;
      };
    };

    networking.firewall.allowedTCPPorts = [80 443];
  };
}