blob: 856b318b3e74626bc6a7f6890e67bd6191f6fc51 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
|
{
config,
inputs,
lib,
pkgsPr,
...
}:
with lib; let
cfg = config.nixfiles.modules.plausible;
in {
disabledModules = ["services/web-apps/plausible.nix"];
imports = [
# TODO Wait for https://github.com/NixOS/nixpkgs/pull/253687
./plausible-nixpkgs-override.nix
];
options.nixfiles.modules.plausible = {
enable = mkEnableOption "Plausible Analytics";
port = mkOption {
description = "Port.";
type = with types; port;
default = 8000;
};
domain = mkOption {
description = "Domain name sans protocol scheme.";
type = with types; nullOr str;
default = "plausible.${config.networking.domain}";
};
};
config = let
db = "plausible";
in
mkIf cfg.enable {
secrets = {
plausible-key = {
file = "${inputs.self}/secrets/plausible-key";
mode = "0444"; # The user is dynamic so the file must be world-readable.
};
plausible-admin-password = {
file = "${inputs.self}/secrets/plausible-admin-password";
mode = "0444"; # The user is dynamic so the file must be world-readable.
};
plausible-smtp-password = {
file = "${inputs.self}/secrets/smtp-password";
mode = "0444"; # The user is dynamic so the file must be world-readable.
};
plausible-release-cookie = {
file = "${inputs.self}/secrets/plausible-release-cookie";
mode = "0444"; # The user is dynamic so the file must be world-readable.
};
};
nixfiles.modules = {
nginx = {
enable = true;
upstreams.plausible.servers."127.0.0.1:${toString cfg.port}" = {};
virtualHosts.${cfg.domain} = {
locations."/" = {
proxyPass = "http://plausible";
proxyWebsockets = true;
};
extraConfig = nginxInternalOnly;
};
};
postgresql = {
enable = true;
extraPostStart = [
''
$PSQL "${db}" -tAc 'GRANT ALL ON SCHEMA "public" TO "${db}"'
$PSQL "${db}" -tAc 'CREATE EXTENSION IF NOT EXISTS citext'
''
];
};
clickhouse.enable = true;
};
services.postgresql = {
ensureDatabases = [db];
ensureUsers = [
{
name = db;
ensurePermissions."DATABASE \"${db}\"" = "ALL";
}
];
};
services.plausible = {
enable = true;
# TODO Wait for https://github.com/NixOS/nixpkgs/pull/253687
package = (pkgsPr 253687 "sha256-36nXNVmZDgf//MrM6/VC7W4Vm013tJ6MlXvYQElhRRw=").plausible;
adminUser = {
name = "admin";
email = "admin@${my.domain.shire}";
passwordFile = config.secrets.plausible-admin-password.path;
activate = false;
};
mail = {
email = "admin+plausible@${my.domain.shire}";
smtp = {
hostAddr = my.domain.shire;
hostPort = 465;
enableSSL = true;
user = "azahi@${my.domain.shire}";
passwordFile = config.secrets.plausible-smtp-password.path;
};
};
database = {
clickhouse = {
setup = false;
url = "http://127.0.0.1:8123/default";
};
postgres = {
setup = true;
dbname = db;
};
};
server = {
baseUrl = "https://${cfg.domain}";
disableRegistration = true;
inherit (cfg) port;
secretKeybaseFile = config.secrets.plausible-key.path;
};
releaseCookiePath = config.secrets.plausible-release-cookie.path;
};
systemd.services.plausible = rec {
after = [
"postgresql.service"
"clickhouse.service"
];
requires = after;
};
};
}
|
