modules/nixos/podman.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48

{
  config,
  inputs,
  lib,
  pkgs,
  ...
}:
with lib;
let
  cfg = config.nixfiles.modules.podman;
in
{
  options.nixfiles.modules.podman.enable = mkEnableOption "Podman";

  config = mkIf cfg.enable {
    assertions = [
      {
        assertion = cfg.enable -> !config.nixfiles.modules.docker.enable;
        message = "Pick only one!";
      }
    ];

    nixfiles.modules.common.shell.aliases.p = "podman";

    secrets.containers-auth = {
      file = "${inputs.self}/secrets/containers-auth";
      path = "${config.dirs.config}/containers/auth.json";
      owner = my.username;
      inherit (config.my) group;
    };

    virtualisation.podman.enable = true;

    environment.systemPackages = with pkgs; [ podman-compose ];

    my.extraGroups = [ "podman" ];

    hm.xdg.configFile = {
      "containers/registries.conf".source = pkgs.writers.writeTOML "containers-registries.toml" {
        registries.search.registries = [ "docker.io" ];
      };

      "containers/storage.conf".source = pkgs.writers.writeTOML "containers-storage.toml" {
        storage.driver = "overlay";
      };
    };
  };
}