modules/nixos/radicale.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58

{
  config,
  inputs,
  lib,
  libNginx,
  ...
}:
with lib;
let
  cfg = config.nixfiles.modules.radicale;
in
{
  options.nixfiles.modules.radicale = {
    enable = mkEnableOption "Radicale";

    domain = mkOption {
      description = "Domain name sans protocol scheme.";
      type = with types; str;
      default = "radicale.${config.networking.domain}";
    };
  };

  config =
    let
      port = 5232;
    in
    mkIf cfg.enable {
      ark.directories = [ "/var/lib/radicale" ];

      secrets.radicale-htpasswd = {
        file = "${inputs.self}/secrets/radicale-htpasswd";
        owner = "radicale";
        group = "radicale";
      };

      nixfiles.modules.nginx = {
        enable = true;
        upstreams.radicale.servers."127.0.0.1:${toString port}" = { };
        virtualHosts.${cfg.domain} = {
          locations."/".proxyPass = "http://radicale";
          extraConfig = libNginx.config.internalOnly;
        };
      };

      services.radicale = {
        enable = true;
        settings = {
          server.hosts = [ "127.0.0.1:${toString port}" ];
          web.type = "none";
          auth = {
            type = "htpasswd";
            htpasswd_filename = config.secrets.radicale-htpasswd.path;
            htpasswd_encryption = "bcrypt";
          };
        };
      };
    };
}