blob: a37d3e7484ab9652d7d392f4f54f2f68e6c8f672 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
|
final: prev: {
bruh = prev.callPackage ./packages/bruh.nix { };
emacsql-sqlite = prev.callPackage ./packages/emacsql-sqlite.nix { };
git-extras = prev.git-extras.overrideAttrs (
_: super: {
postPatch =
(super.postPatch or "")
+ ''
substituteInPlace bin/git-setup \
--replace 'Initial commit' 'chore: init'
'';
}
);
grc = prev.grc.overrideAttrs (
_: super: {
version = "unstable-2021-08-12";
src = final.fetchFromGitHub {
owner = "garabik";
repo = "grc";
rev = "4d6a51fd78ad7e19af8dd12b2a828d1807267079";
hash = "sha256-SmOZrgV0lgLryFoxADU15IKJ7jhxXar0MgbsV/z1GaE=";
};
patches = (super.patches or [ ]) ++ [
(final.fetchpatch {
url = "https://patch-diff.githubusercontent.com/raw/garabik/grc/pull/214.patch";
hash = "sha256-VNr9jl5oFbFNJbGsjflwFV3oTbCzJ0lBIZA4eyeoXLY=";
})
];
}
);
hiccup = prev.callPackage ./packages/hiccup.nix { };
logcli = prev.grafana-loki.overrideAttrs (
_: super: {
pname = "logcli";
subPackages = [ "cmd/logcli" ];
nativeBuildInputs = super.nativeBuildInputs ++ [ final.installShellFiles ];
postInstall =
(super.postInstall or "")
+ ''
installShellCompletion --cmd logcli \
--bash <($out/bin/logcli --completion--script-bash) \
--zsh <($out/bin/logcli --completion-script-zsh)
'';
preFixup = null;
}
);
myip = prev.callPackage ./packages/myip.nix { };
nixfiles = prev.callPackage ./packages/nixfiles.nix { };
nixfmt = prev.nixfmt-rfc-style;
openssl_1_0_0 = prev.callPackage ./packages/openssl_1_0_0.nix { };
parinfer-rust = prev.callPackage ./packages/parinfer-rust.nix { };
# FIXME https://nixpk.gs/pr-tracker.html?pr=307505
poetry = prev.poetry.overrideAttrs (finalAttrs: {
nativeBuildInputs = (finalAttrs.nativeBuildInputs or [ ]) ++ [
prev.python3Packages.pythonRelaxDepsHook
];
pythonRelaxDeps = [ "dulwich" ];
});
prismlauncher-unwrapped =
(prev.prismlauncher-unwrapped.override (finalAttrs: {
stdenv = final.useMoldLinker finalAttrs.stdenv;
})).overrideAttrs
(
_: super: {
patches = (super.patches or [ ]) ++ [ ./patches/prismlauncher-allow-offline-accounts.patch ];
}
);
telegram-desktop =
(prev.telegram-desktop.override (finalAttrs: {
stdenv = final.useMoldLinker finalAttrs.stdenv;
})).overrideAttrs
(_: super: { patches = (super.patches or [ ]) ++ [ ./patches/telegram-desktop-no-ads.patch ]; });
vesktop = prev.vesktop.overrideAttrs (
_: super: {
nativeBuildInputs = super.nativeBuildInputs ++ [ final.imagemagick ];
patches = (super.patches or [ ]) ++ [ ./patches/vesktop-no-anime.patch ];
postInstall =
(super.postInstall or "")
+ ''
rm -rf $out/share/icons/hicolor/*
for size in 16 24 32 48 64 96; do
convert -scale $size icon.png $size.png
install -Dm644 $size.png $out/share/icons/hicolor/''${size}x''${size}/apps/vesktop.png
done
'';
}
);
}
|
