1 files changed, 59 insertions, 0 deletions
diff --git a/x11-wm/shod/shod-0.4.0.ebuild b/x11-wm/shod/shod-0.4.0.ebuild
new file mode 100644
index 0000000..41f79de
--- /dev/null
+++ b/x11-wm/shod/shod-0.4.0.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+if [[ ${PV} == *9999 ]]; then
+	SCM="git-r3"
+	EGIT_REPO_URI="https://github.com/phillbush/shod.git"
+fi
+
+inherit toolchain-funcs ${SCM}
+
+DESCRIPTION="Hybrid (floating and tiling) window manager"
+HOMEPAGE="https://github.com/phillbush/shod"
+
+if [[ ${PV} == *9999 ]]; then
+	SRC_URI=""
+	KEYWORDS=""
+else
+	SRC_URI="https://github.com/phillbush/shod/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE=""
+
+DEPEND="
+	x11-libs/libX11
+	x11-libs/libXinerama
+"
+RDEPEND="${DEPEND}"
+BDEPEND=""
+
+DOCS=(
+	README
+	examples/
+)
+
+src_prepare() {
+	sed -e '/^CPPFLAGS/d' \
+		-e 's/FLAGS =/FLAGS +=/g' \
+		-i config.mk || die
+
+	default
+}
+
+src_compile() {
+	emake \
+		CC="$(tc-getCC)"
+}
+
+src_install() {
+	emake install \
+		DESTDIR="${D}" \
+		PREFIX="${EPREFIX}/usr"
+
+	einstalldocs
+}