flake.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64

{
  description = "Personal XMonad configuration.";

  inputs = {
    nixpkgs = {
      type = "github";
      owner = "NixOS";
      repo = "nixpkgs";
      ref = "nixpkgs-unstable";
    };

    flake-utils = {
      type = "github";
      owner = "numtide";
      repo = "flake-utils";
      ref = "master";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    flake-compat = {
      type = "github";
      owner = "edolstra";
      repo = "flake-compat";
      ref = "master";
      flake = false;
    };
  };

  outputs = { self, nixpkgs, flake-utils, ... }:
    flake-utils.lib.eachDefaultSystem (system:
      let
        pkgs = nixpkgs.legacyPackages.${system};

        project = returnShellEnv:
          pkgs.haskellPackages.developPackage {
            inherit returnShellEnv;
            name = "xmonad-ng";
            root = ./.;
            overrides = self: _:
              with pkgs.haskell.lib;
              let version = "0.17.0";
              in {
                xmonad = dontCheck (self.callHackage "xmonad" version { });
                xmonad-contrib =
                  dontCheck (self.callHackage "xmonad-contrib" version { });
              };
            modifier = drv:
              pkgs.haskell.lib.addBuildTools drv (with pkgs.haskellPackages; [
                brittany
                cabal-install
                haskell-language-server
                hlint
                hpack
                stack
              ]);
          };
      in {
        defaultPackage = project false;

        devShell = project true;
      }) // {
        overlay = _: _: { xmonad-ng = self.defaultPackage; };
      };
}